An old program I found

This is still taking up space in a library on my machine (it runs in 
GWBASIC, if you still have an interpreter):

  10 DIM DAY$(12)
  20 FOR I=1 TO 12
  30 READ DAY$(I)
  40 NEXT I
  50 FOR I=1 TO 12
  60 PRINT "On the ";DAY$(I);" day of Christmas, my true love gave to me:"
  70 IF I = 1 THEN GOTO 100
  80 PLAY "t150o2l8ccl4cl8ffl4fl8efgab-gl2a"
  90 GOTO 110
  100 PLAY "t150o2l8ccl4cl8ffl4fl8efgab-gl4a."
  110 ON 13-I GOTO 120,140,160,180,200,220,240,260,350,370,390,440
  120 PRINT "Twelve drummers drumming,"
  130 PLAY "o3l4co2l8gab-g"
  140 PRINT "Eleven pipers piping,"
  150 PLAY "o3l8cco2l8gab-g"
  160 PRINT "Ten lords a-leaping,"
  170 PLAY "o3l4co2l8gab-g"
  180 PRINT "Nine ladies dancing,"
  190 PLAY "o3l4co2l8gab-g"
  200 PRINT "Eight maids a-milking,"
  210 PLAY "o3l4co2l8gab-g"
  220 PRINT "Seven swans a-swimming,"
  230 PLAY "o3l8cco2l8gab-g"
  240 PRINT "Six geese a-laying,"
  250 PLAY "o3l4co2l8gab-g"
  260 PRINT "Five golden rings,"
  270 PLAY "o3l2cl4do2bl2o3mlcmnc"
  280 PRINT "Four calling birds,"
  290 PLAY "o3l8co2b-agl4f"
  300 PRINT "Three French hens,"
  310 PLAY "o2l4b-df"
  320 PRINT "Two turtle doves,"
  330 PLAY "l8gfedl4c"
  340 GOTO 410
  350 PRINT "Four calling birds,"
  360 PLAY "o3l4co2l8gal4b-"
  370 PRINT "Three French hens,"
  380 PLAY "o3l4co2l8gal4b-"
  390 PRINT "Two turtle doves,"
  400 PLAY "o3l4co2l8gal4b-"
  410 PRINT "And a ";
  420 PLAY "l8ab-"
  430 GOTO 460
  440 PRINT "A ";
  450 PLAY "l8b-"
  460 PRINT "partridge in a pear tree."
  470 PLAY "o3l4cl8do2b-afl4gl2f."
  480 PRINT ""
  490 NEXT I
  500 PRINT "We..."
  510 PLAY "t250o2l2c"
  515 PRINT "Wish you a Merry Christmas,"
  520 PLAY "l4fl8fgfel4dd"
  530 PRINT "We wish you a Merry Christmas,"
  540 PLAY "l4dgl8gagfl4ec"
  550 PRINT "We wish you a Merry Christmas,"
  560 PLAY "l4cal8ab-agl4fd"
  570 PRINT "And a Happy New Year!"
  580 PLAY "l8ccl4dgel2f"
  590 PRINT "With tidings of joy,"
  600 PLAY "l4cfffl2e"
  610 PRINT "For you and your kin,"
  620 PLAY "l4efedl2c"
  630 PRINT "We wish you a Merry Christmas,"
  640 PLAY "l4gal8ggggo3l4co2l4c"
  650 PRINT "And a Happy New Year!"
  660 PLAY "l8ccl4dgemll2ff"
  910 DATA "first","second","third","fourth","fifth","sixth"
  920 DATA "seventh","eighth","ninth","tenth","eleventh","twelfth"




-- 
Regards, Pete
pgranzeau at cox.net